日期計算(日期計算器在線天數)

小伙伴們好啊，今天你上班了嗎？咱們來分享一組常用的日期計算公式，收藏一下，說不定哪天就用上了呢。1、今天是幾號

=DAY(NOW())

2、現在是幾月份

=MONTH(NOW())

3、今天是星期幾

=WEEKDAY(NOW(),2)

4、當前的日期

=TODAY()

TODAY函數和NOW函數類似，不需要參數，只要一對括號就夠了。

5、當前的年份

=YEAR(NOW())

6、今天是本年度的第幾周

=WEEKNUM(NOW())

WEEKNUM函數用于返回一年中的周數，第1參數是要判斷的日期，第二參數省略，表示一周的第一天是星期日。如果希望一周的第一天是星期一，可以將第二參數寫成2。

7、現在是幾季度

=LEN(2^MONTH(NOW()))

這個公式之前在咱們的公眾號里也推送過，應該是一位數學大神研究出來的。先使用MONTH(NOW())部分算出當前日期的月份，然后用2做底數，用月份做指數，來計算乘冪。然后使用LEN函數計算出的乘冪有幾位數，這個位數恰好就是季度數。

8、現在是今年的第幾天

=TODAY()-"1-1"+1

在Excel中，不指定年份的日期會被視作當前系統年份。本例中使用TODAY()-"1-1"，就是用當前日期減去本年度的1月1日，這樣計算出當前日期距離1月1日有多少天，最后再加上一個，結果就是今年的第幾天了。

9、當前季度有多少天

=COUPDAYS(NOW(),"9999-1",4,1)

COUPDAYS函數是一個財務專用函數，用于返回結算日所在付息期的天數。

第一參數是證券結算日，本例使用系統當前日期。

第二參數是證券到期日，本例使用一個非常大的日期——9999年1月1日。

第三參數和第四參數分別指定付息次數和日計數基準類型。

最終計算結果實際上是當前日期所在付息周期的天數。

10、今天是本月的第幾周

=INT((DAY(NOW())+MOD(NOW()-DAY(NOW()),7)-1)/7)+1

這個公式的計算過程有點小復雜，也是按數學規律來的。有余數計算，還有取整計算，大家會套用就可以了，公式中的NOW()部分，可以換成實際要判斷的日期。

11、本月有多少天？

=DAY(EOMONTH(NOW(),0))

EOMONTH函數的作用是返回某個日期所在月份的最后一天。先使用NOW函數得到系統當前日期，然后用EOMONTH得到當前日期所在的月份的月末日期，最后再使用DAY函數計算出月末日期的“天”。

12、本月還剩多少天

=EOMONTH(NOW(),0)-TODAY()

先使用EOMONTH函數計算出當前日期的月末日期，然后減去當前日期。

13、下個工作日是哪天？

=WORKDAY(TODAY(),1)

WORKDAY函數用于計算指定工作日之前或之后的日期，。這里的工作日默認是指除了周六和周日的日期。

第1參數是起始日期，第二參數是工作日，第三參數可以省略，用于指定要排除的法定節假日。比如要排除春節，就可以在單元格中依次羅列出春節放假的全部日期，WORKDAY函數的第三參數引用這個區域就可以了。

14、今年是不是閏年

=IF(COUNT(-"2-29"),"是","否")

"2-29"部分，使用了沒有指定年份的文本型日期，系統會按當前年份進行識別。前面加上一個負數，如果當前年份的2月29日這個日期存在，會返回一個負數，如果當前年份的2月29日不存在，加上負數后就變成錯誤值了。

然后使用COUNT函數函數計算數值個數，日期存在，結果為1，日期不存在，結果為0。

然后使用IF函數，根據COUNT的結果進行判斷。在IF函數的第1參數中，0相當于邏輯值FALSE，不等于0的其他數值則相當于TRUE，最終返回“是”或“否”。

16、1973年6月8日出生的寶寶幾歲了？

=DATEDIF("2012-6-28",NOW(),"y")

DATEDIF函數用于計算兩個日期之間間隔的整年數或整月數。

第一參數是起始日期，第二參數是截止日期，第三參數用于指定間隔類型。y表示年，m表示月。

17、今年的母親節是哪天？

=FLOOR("5-6",7)+8

每年5月的第二個星期日是母親節。

先使用"5-6"得到系統當前年份的5月6日。再使用FLOOR函數，將當前年份的5月6日向下舍入到7的倍數，得到5月6日之前最后一個星期六的日期。

加上8，就是五月份的第二個星期。

好了，今天咱們的內容就是這些吧，祝大家新年新起點，牛年步步高！

圖文制作：祝洪忠